barcode

@profile(t1);
import io from "io";
import fs from "fs";
import gfx from "gfx";
import image from "image";
import barcode from "barcode";

fn main() -> i32 {
    let code: barcode.Symbol = barcode.qr("https://tapelang.org") or {
        io.println("no QR code: {err}");
        return 1;
    };
    var picture: gfx.Surface = barcode.render(&code, &barcode.Style {}) or { return 2; };
    let png = image.encode(&picture, image.Format.Png) or { return 3; };
    fs.write_file("tapelang.png", png.slice()) or { return 4; };
    picture.free();
    return 0;
}

A barcode is made in two steps. encode turns your data into a Symbol, the grid of light and dark modules the standard asks for. Then you draw the symbol: render gives a gfx.Surface (what image.decode gives for a PNG, so you can save it, draw it in a window or print it), svg gives an SVG document. barcode is a pure module: it reads and writes no files.

Kinds

Options:

A 2D symbol grows with its data; QR then uses the error correction left over in that size, so a short link at level M may come out at level Q. Each symbology is also a module of its own with every option it has (barcode_qr, barcode_datamatrix, barcode_aztec, barcode_pdf417, barcode_linear); its encode gives the same Symbol.

BarcodeError:

Style

let style: barcode.Style = barcode.Style {
    shape: barcode.Shape.Rounded;           // modules joined into round blobs
    eye: barcode.EyeShape.Rounded;          // the three corner squares
    eye_core: barcode.EyeShape.Circle;
    fill: barcode.Fill.Linear;              // a gradient
    dark: #6A00F4;
    dark2: #00B4D8;
    angle: 45.0;
};

The finders are always drawn whole in their own shape, whatever the modules’ shape, so a reader still finds them.

Keep the colours far apart: dark modules on a light background, with a barcode.contrast of 3 or more for the modules, the eyes and the gradient’s ends. Gold eyes on white (2.2) already fail; most phone cameras do not read light modules on a dark background either.

A logo

var logo: gfx.Surface = image.decode(logo_png) or { return 1; };
let code: barcode.Symbol = barcode.encode(barcode.Kind.Qr, url, barcode.Options {
    ec: barcode.Ec.High;
}) or { return 2; };
var picture: gfx.Surface = barcode.render(&code, &barcode.Style {
    logo: &logo;
    logo_size: 0.22;
    logo_round: 1.5;
}) or {
    io.println("{err}");        // LogoTooLarge: a smaller logo, or more error correction
    return 3;
};

The modules under the logo are cleared, so the data they held is lost and the error correction has to restore it. render and svg count what the logo hides and refuse it (LogoTooLarge) when it hides more than three quarters of what the code can restore, leaving the rest for a crease or a glare. Ask for Ec.High when you put a logo on a QR code: it takes a logo of about a fifth of its width; at the default level M only a small one fits. The finders, timing and format modules are never cleared.

Logos are for QR codes. An Aztec code has its bullseye in the middle, so it takes none; a Data Matrix code takes a small one in the sizes up to 26 x 26 (one data region, no alignment lines through the middle) when it has room to spare; PDF417’s error correction is spread too thin for one. Each refuses with LogoTooLarge rather than giving a code that does not scan.

For svg, give the logo as logo_href: a URL the SVG will be shown next to, or a data:image/png;base64,... URI you make with image.encode and encoding.base64.

1D barcodes

let ean: barcode.Symbol = barcode.encode(barcode.Kind.Ean13, "400638133393", barcode.Options {}) or { return 1; };
io.println(ean.text);         // "4006381333931": the check digit added

Give EAN and UPC codes without their check digit and it is added, or with it and it is checked (BadCheckDigit). A 1D symbol is one module high: render draws its bars bar_height modules tall with the text under them.

Your own symbology

A Symbol is a grid you can fill yourself, so a barcode the stdlib lacks is drawn like the others:

import barcode_core from "barcode_core";

var s: barcode_core.Symbol = barcode_core.symbol(9, 9);
s.set(4, 4, true, barcode_core.ROLE_DATA);
s.quiet = 2;
var picture: gfx.Surface = barcode.render(&s, &barcode.Style { shape: barcode.Shape.Dot; }) or { return 1; };

Last modified: 2026-11-05 13:29:35 UTC